aplicar una formula de una base de datos de una hoja

En una hoja 1 tengo los siguientes datos
A B C
1 RECIBO 001-005 1900
2 RECIBO 006-010 2500
3 RECIBO 011-015 6500

En otra Hoja 2 del mismo archivo se ingresa los datos de la siguiente forma

A B C D E F
1 RECIBO IMPORTE RECIBO IMPORTE RECIBO IMPORTE
2 001 560 006 350 011 2100
3 002 1000 007 850 012 1000
4 003 140 008 150 013 1000
5 004 100 009 850 014 2000
6 005 100 010 300 015 400
TOTAL 1900 TOTAL 2500 TOTAL 6500

Mi consulta es que formula podria utilizar en la hoja 1 en la celda A1 A2 y A3 para trasladar los datos de la hoja 2, asimismo los totales de la B1 B2 y B3 en la hoja 1

Gracias por su ayuda

Hoja1

	A	B	C	D	E	F
3	RECIBO	IMPORTE	RECIBO	IMPORTE	RECIBO	IMPORTE
4	001	560	006	350	011	2100
5	002	1000	007	850	012	1000
6	003	140	008	150	013	1000
7	004	100	009	850	014	2000
8	005	100	010	300	015	400
9	TOTAL	1900		2500		6500
10
11
12	RECIBO 001 - 005	1900
13	RECIBO 006 - 010	2500
14	RECIBO 011 - 015	6500
15
16
17	como seria la formula para jalar de la hoja 2  los datos
18	para que en la hoja 1 el resultado sea  "RECIBO
19	001-005" con los datos de la hoja 2
20

Spreadsheet Formulas

Cell Formula B9 =SUMA(B4:B8) D9 =SUMA(D4:D8) F9 =SUMA(F4:F8) A12 ="RECIBO "&TEXTO(MIN(DESREF(Hoja2!$A$2;;(FILA(A1)-FILA($A$1))*2;5));"000")&" - "&TEXTO(MAX(DESREF(Hoja2!$A$2;;(FILA(A1)-FILA($A$1))*2;5));"000") B12 =SUMA(DESREF(Hoja2!$B$2;;(FILA(A1)-FILA($A$1))*2;5)) A13 ="RECIBO "&TEXTO(MIN(DESREF(Hoja2!$A$2;;(FILA(A2)-FILA($A$1))*2;5));"000")&" - "&TEXTO(MAX(DESREF(Hoja2!$A$2;;(FILA(A2)-FILA($A$1))*2;5));"000") B13 =SUMA(DESREF(Hoja2!$B$2;;(FILA(A2)-FILA($A$1))*2;5)) A14 ="RECIBO "&TEXTO(MIN(DESREF(Hoja2!$A$2;;(FILA(A3)-FILA($A$1))*2;5));"000")&" - "&TEXTO(MAX(DESREF(Hoja2!$A$2;;(FILA(A3)-FILA($A$1))*2;5));"000") B14 =SUMA(DESREF(Hoja2!$B$2;;(FILA(A3)-FILA($A$1))*2;5))

Excel tables to the web >> [Tienes que estar registrado y conectado para ver este vínculo]

Gracias ingeniero Galileo, solo que en mi caso el excel se utiliza la (,) y no (;) pero excelente su respuesta. Encantado gracias por todo.